運営メンバー紹介

なっとー
どうも、なっとーです。

前回の記事では、ルーレットの出目データを効率的に集める方法について書きました。

今回は、集めた出目データを分析して攻略の糸口を見つけ出す、具体的なやり方についてです。

実際の分析作業をお見せしながらご説明していきます。エクセルでの分析ですが、エクセルに馴染みのない方でも分かるように出来るだけ丁寧に書いていきますね。

検証するのは

  • 赤黒の各種ベット手法
  • 0 の直前出目
  • 地雷ベットドマンの直前出目

の3種類です。10万投の出目データを使って実際に分析していきます。

ここでご紹介する数式などが使えるようになれば、他にも色々と分析できるようになるはずです。

赤黒ベットで勝てる賭け方はあるのか?

赤黒ベットの分析からスタートします。

赤黒の賭け方って色々とあるじゃないですか。「ルーレット 赤黒 必勝法」とかで検索すると、必勝法がいっぱい出てきます。

ああいうサイト見てると、「本当に勝てるの?」って思いますよね。「必勝法って書いてるお前、ホントに勝ててんの?」って。

なっとー
出目データ分析で検証してみます(キリッ

検証する赤黒ベットの賭け方は次の通りです。

  • シンプル順張り
  • シンプル逆張り
  • 2連続順張り
  • 2連続逆張り
  • N連続逆張り(N=2,3,4,…9)

赤黒ベット シンプル順張り・逆張りの検証

「シンプル順張り」というのは、直前出目の色と同じ色に賭けるベット方法のことです。直前出目が赤なら赤、黒なら黒、緑(0)ならルック。

シンプル逆張りはその真逆で、直前出目の色と反対の色に賭けます。直前が赤なら黒、黒なら赤、緑(0)ならルックです。

手順① 出目データを横一列に並べる

一列にした出目データ

上のように出目データを横一列に並べると、数式による処理が簡単になります。僕は1つのシートにつき10,000コの出目を横一列に並べています。

出目の向きは、オンカジサイトの実際の表示と同じ「右から左」です。つまり、一番左が最新の出目で、右にいくにつれて古い出目になっていきます。

真ん中あたりの「⇦」は、データの境界をしめすマークです。⇦マークが下に付いている12と右横の1は連続していません。別々の日に取ったデータだからです。

 

エクセルの仕様上、列の数の最大値は16,384列なので、10,000投ごとにシートを分けています。10万投ならシートが10コ必要となります。

なっとー
行数の最大値は百万超えなので、縦一列のほうが良かったかもです。。。

下半身鬼尾
詰めが甘いなw

手順② 赤黒のどちらに賭けるか数式で指定する

赤黒シンプル順張り逆張りの数式

つぎに、その時々で赤黒のどちらに賭けるのか?を指定する数式を入れていきます。

ここでは、「順張りBET」と「逆張りBET」の行を用意して、そこに数式を入れています。

順張りBETに入っている数式でご説明します。緑枠で囲まれたセルには、つぎのような数式が入っています。↓

=IF(OR(C4="⇦",D2="緑"),"",D2)

ガチムチ
・・・(怒)

なっとー
…はい。もちろん一つ一つご説明します!
IF関数の意味と使い方
分析ではIF関数を多用します。IF関数の構文(書き方)は次のとおりです。↓
=IF(論理式,[値が真の場合],[値が偽の場合])
意味不明なので日本語に置き換えると、
=IF(質問,[答えがYESの場合の出力値],[答えがNOの場合の出力値])
のようになります。まだ分かりにくいので、さらに身近な例を。↓
=IF(合コンの相手は可愛いか?,"全額おごる","キッチリ割り勘")
こんな感じです。
OR関数の意味と使い方
IF関数の中で複数の条件を使いたいときはOR関数を使います。
=IF(OR(論理式A,論理式B),[値が真の場合],[値が偽の場合])
論理式A・Bの少なくともどちらか1つを満たせば「真」、どちらも満たさなければ「偽」です。合コンの例でいえば
=IF(OR(合コンの相手は可愛いか?,合コンの相手はエロいか?),"おごる","割り勘")
となります。

ここまでの内容を踏まえて、もういちど数式を見てみます。

=IF(OR(C4="⇦",D2="緑"),"",D2)

数式の意味は、

「C4セルが⇦であるかD2セルが緑の場合は、空白を出力。そうでない場合はD2セルと同じ内容を出力」

となります。

⇦マークが付いている出目はデータの始まりの出目ですので、直前の出目データがありません。ということで除外したいので、空白を出力します。空白は半角の「"(ダブルクォーテーション)」を2つ並べればOKです(「""」のように)。

直前が0(緑)の場合も、賭けられないので除外します。

データの始まりでもなく直前の出目が0(緑)でもないなら、シンプル順張りでは直前出目と同じ色を賭けていきます。

なので、数式の「値が偽の場合」の部分には、直前出目の色が表示されているセル「D2」と入力します。

1つのセルに数式を入れたら、あとは同じ行(順張りBETの行)のセル全てにコピペすればOKです。

 

手順③ 勝敗を数式で表示する

次に、賭けた結果の勝敗を数式で自動で表示させます。「順張り結果」「逆張り結果」の行ですね。↓

赤黒ベットの結果表示数式

=IF(C8="","",IF(C8=C2,"◯","×"))

数式はIF関数が入れ子構造になっています。

IF関数の入れ子構造
IF関数の中にIF関数を入れることができます(入れ子構造)。つまり、こういうことです。↓
=IF(合コンの相手は可愛いか?,IF(所持金に余裕があるか?,"おごる","割り勘"),"割り勘")
[値が真の場合]の部分が丸々IF関数になっています。
最初の質問で「YES」なら次の所持金についての質問に移り、おごるか割り勘かが決まる。可愛くない(最初の質問の答えがNO)なら無条件で割り勘になります。

BETのセルが空白なら賭けないので、結果のセルも空白にします。
(※ =IF(C8="","",IF(C8=C2,"◯","×")) の太字の部分)

空白でないなら赤黒どちらかに賭けているので、次に進みます。BETのセルの内容(赤or黒)と実際の出目の色が一致していれば、「◯」。違うなら「×」です。
(※ =IF(C8="","",IF(C8=C2,"◯","×")) の太字部分)

1つのセルに数式を入力したら、同じ行のセル全部にコピペすればOKです。

これで結果が全て判明しました。あとは集計だけです。

 

手順④ 結果を集計する

集計と言っても、順張り逆張りそれぞれについて◯と×の数を数えるだけです。COUNTIF関数を使います。

赤黒BET勝敗集計数式

=COUNTIF($C$9:$NTR$9,"◯")
COUNTIF関数
COUNTIF関数を使えば、特定の範囲のなかで条件に合致するセルの個数を調べることができます。
=COUNTIF(検索範囲,検索条件)
という構文です。合コンで例えると(略
検索範囲はマウスでドラッグすれば指定できます。
絶対参照 $C$9
検索範囲を指定する部分を見ると、セルの部分にドルマーク$が2つ付いています。$C$9:$NTR$9 のところですね。これは絶対参照を意味していて、コピペしても変化させて欲しくないときに使います。
数式の入ったセルをコピペすると、セルの位置に応じて数式の中のセルの位置も変わってくれます。だから、ただコピペするだけで数式がきちんと働いてくれるわけです。
ただ今回は◯を検索する範囲はどのセルでも同一なので、コピペ時に変わって欲しくありません。ということで絶対参照にします。検索範囲のセル入力時にF4キーを押せばOKです。

上の数式は、「C9セルからNTR9セルまでの範囲で、内容が◯のセルの個数を数えろ」という意味になっています。

順張りの×と逆張りの◯×も同様にCOUNTIF関数で数えます。

勝率は単純に割り算の数式「◯の個数 ÷ 全体の個数」を入れ、表示形式をパーセンテージにしているだけです。

シンプル順張り・逆張りの結果発表

赤黒ベットシンプル順張り逆張りの10万投検証結果

ガチムチ
やる気のねえ表だなw

皆さんの予想通り、順張りも逆張りも理論値(48.64%=18/37)の近くに落ち着きました。

わずかに理論値よりもプラスなのは、たぶん偶然です。

また、50%を超えないかぎり利益は出ないので、当然ですが必勝法ではありません。

こんな感じで、他のもっと複雑な検証でも

  1. ベットのロジックを数式で表す
  2. 勝敗や損益を数式で表示する
  3. 集計する

という流れで分析していきます。

赤黒ベット 2連続順張り・逆張りの検証

2連続順張りは、「赤赤」や「黒黒」など同じ色が2連続したらその色に賭ける方法です。

2連続逆張りは真逆です。「赤赤」ときたら黒に、「黒黒」ときたら赤に賭けていきます。

 

手順① 直近2投のパターンを表示する

出目の色は「赤」「黒」「緑」の3色ですので、直近2投の色の組み合わせは3×3で9パターンあります。

2連続順張り(逆張り)では「赤赤」と「黒黒」のときだけベットするので、まずはその時点で直近2投のパターンがどうなっているのかを表示させます。

赤黒ベット2連続

=IF(ISBLANK(C3),"",IF(OR(C4="⇦",D4="⇦"),"",D2&E2))

IF(ISBLANK(C3),"",IF関数) という形になっています。「C3セルが空白なら何も出さないでね」という意味です。

10,000投分のセルと数式を用意しているけど出目が全部埋まっていない場合、空白セルを参照した数式はエラーになってしまいます。これが見た目的にウザいので、この処理をしています。

ISBLANK関数
対象のセルが空白かどうかを判定する関数です。IF関数の中で論理式として使うことが出来ます。例えば
=IF(ISBLANK(C3),"","空白でない")
と書けば、C3セルが空白なら何も出さず、空白でないなら「空白でない」と出力されます。
C3セルに数式が入っていて結果として空白になっている場合、空白とは判定されません。この場合にも空白を出力したいときは
=IF(C3="","","空白でない")
とやればOKです。
IF(OR(C4="⇦",D4="⇦"),"",D2&E2)

関数の実質的な中身は上の部分です。

「C4セルかD4セルに⇦マークが入っているなら空白、そうでないならD2セルの内容とE2セルの内容をつなげて出力してね」

という意味になっています。

まず、データの始まりの1投目と2投目には、直近2投のデータがありません。だから除外します。
(→ IF(OR(C4="⇦",D4="⇦"),"", の部分)

次に、直近2投のデータがある場合はその2投の色をつなげたものを出力しています。
D2&E2 の部分ですね。

数式中の & の意味と使い方
数式の中で & を使うと、セルの内容を繋げることができます。
上の例ではD2の内容は「赤」でE2の内容も「赤」ですので、&で繋げると「赤赤」となります。

 

手順② ベット判定の数式を入れる

ここまでの処理で、直近2投の色のパターンを表示できました。

赤赤 赤黒 赤緑 黒黒 黒赤 黒緑 緑緑 緑赤 緑黒 の9パターンのうち、ベットするのは赤と黒が2連続したときだけです。これを数式で表します。↓

赤黒2連続順張り逆張りベット数式

=IF(C8="","",IF(C8="赤赤","赤",IF(C8="黒黒","黒","")))
IF関数の中にIF関数が2つ入った入れ子構造になっていますが、そこまで複雑じゃないです。

一番外側の =IF(C8="","",IF関数) の部分は、「C8セルが空白なら空白を出力」という意味です。

C8セルは直近2投の色ですので、ここが空白ならベットできません。ということで除外です。

IF(C8="赤赤","赤",IF(C8="黒黒","黒",""))
  1. C8セル(直近2投の色)が赤赤なら赤を出力。それ以外なら次に進む。
  2. C8セルが黒黒なら黒を出力。それ以外なら空白。

これまでのIF関数と使い方は同じなので分かりやすいと思います。

逆張りBETの行に入っている数式も、同様の書き方でOKです。

手順③ 結果判定と集計

ベットの結果判定と集計のための数式は、赤黒シンプル順張りのものと同じでOKです。

2連続順張り・逆張りの結果発表

シートごと(1万投ごと)に集計して、それを足し合わせて10万投全体の結果を出しました。↓

10万投赤黒2連続順張り逆張り結果

今回も理論値に近い結果となりました。逆張りのほうが勝率が高くなっていますが、誤差レベルです。

n連続逆張りの検証

次に、逆張りに特化して検証していきます。

必勝法でよく目にするのが、同じ結果が続いたあとの逆張りベット。赤黒でいえば

「5回黒が続いたら、そこから赤に賭ける。マーチンで5回まで追う」

みたいなやつですね。

これは疑いようもなく「ツラ切り思考」です。オンカジ必勝.comの読者さんなら、これがどれだけ危険かお分かりだと思います。まじで死にますw

でも、

「これだけ続いたら、そろそろ逆がくるだろ」

と考えてしまう気持ちは分かります。僕もそう思っちゃいます。たぶん人間の本能です。

しかし、「赤か黒か」はバリバリ独立事象ですので、過去の結果の影響はゼロです。赤が10連続していても、次に黒が来る確率は18/37です。

ガチムチ
おいおい、嘘つくんじゃねぇよ。このガリ勉野郎が!

なっとー
…ということで、検証して確かめてみます

手順① 直近n投の色パターンを表示する

今回は、2連続から9連続までを検証します。さっきから「n連続」とか「直近n投」とか気持ち悪いこと書いていますが、このnには2~9の数字が入ります。

赤か黒が2連続・3連続・4連続…9連続したあとに逆張りベットしたら、それぞれ勝率はどうなるのか?を検証するということです。

やりかたは2連続逆張りベットの検証と基本的に同じです。

赤黒n連続逆張りベットの検証

n=2 n=3 n=4 … n=9 の行を用意して、それぞれの行の全セルにベット判定の数式を入れていきます。

ISBLANK関数の部分をのぞくと、数式はつぎの通りです。↓

=IF(OR(C$4="⇦",D$4="⇦",E$4="⇦"),"",D$2&E$2&F$2)

「C4セルD4セルE4セルのどれかに⇦マークが入っているなら空白を表示。それ以外ならD2セル・E2セル・F2セルの3つを繋げたものを表示」

という意味です。2連続の検証のときと同じ考え方ですね。

セルの複合参照 C$4
上の数式ではセルの複合参照というものを使っています。絶対参照は $C$4 のように$マークが2つ付いていますが、複合参照は1つです。F4キーを1回押すと絶対参照になりますが、2回か3回押すと複合参照になります。
絶対参照は、数式が入ったセルをコピペしても参照セルを変えてほしくないときに使いました。一方の相対参照は、行か列のどちらかは変えてほしくないときに使います。
C$4なら、コピペしても行は固定されます。$C4なら、列が固定されます。

n=4 n=5 … n=9 も同様に数式を入れていきます。たとえば、n=4だと

=IF(ISBLANK(C$3),"",IF(OR(C$4="⇦",D$4="⇦",E$4="⇦",F$4="⇦"),"",D$2&E$2&F$2&G$2))

のようになります。参照するセルの数が増えるだけで、内容は変わりません。

赤黒n連続逆張りベットの検証02

ビチ子
キモーいwww

手順②③ 結果判定と集計

◯×の結果判定と集計のための数式は、これまでのもと同じ考え方で作ればOKです。

n=2 n=3 … n=9 ごとに数式を用意して、結果を集計していきます。

赤黒n連続逆張りベットの結果発表

10万投で検証した結果は↓のようになりました。

赤黒n連続逆張りベットの検証結果

若干のバラツキはあるものの、理論値付近の確率となりました。

少なくとも、「◯回連続したから、逆張りが有利になる!」とは口が裂けても言えない結果です。

赤黒は最大で何回連続するのか?

次に、赤黒は最大で何回連続するのか?、10万投の範囲内で調べてみました。完全に興味本位です。

結果は、16回でした。10万投のうち、16連続したのが2回ありました。

赤(黒)が16連続する確率は約0.001%なので「起こり得ない」レベルの事象だと思いがちですが、実際に起こるんですね。

データが100万投、1,000万投と増えていけば、20連続とか30連続とかも出現するのかもしれません。

赤黒の連続回数ごとの出現回数

上は、連続回数ごとの出現回数です。10連続以上は合計で150回出現しています。

10万投で150回ですから、1,000投だと1.5回です。ルーレットを666投分眺めていれば、1回くらいは10連続に遭遇する可能性が高いということですね。

エボリューションのスピードルーレットですと、4~5時間やり続けると1回くらいは10連続以上が出現する感じです。

ご参考までに、ツラ回数を算出する数式がこちらです。↓

赤黒ツラ回数数式

=IF(C2="緑","",IF(OR(C4="⇦",C2<>D2),1,D8+1))

=IF(C2="緑","",IF関数) の部分は0(緑)を除外するためのものです。関数の本体は

IF(OR(C4="⇦",C2<>D2),1,D8+1)

の部分です。

「C4セルに⇦マークがあるか、C2セルとD2セルが異なる内容なら1を、それ以外なら右隣のセルに1をプラスした結果を表示」

という意味です。

ツラの始まりに1と表示させて、ツラが続くかぎり1を加えていく感じです。

 

インサイドベットの検証方法

ルーレット インサイドベット

ここまでは、赤黒=アウトサイドベットの検証でした。

赤黒・ハイロー・オッドイーブンなどのアウトサイドベットは、ライブルーレットでもディーラーがコントロールできません。だから、ガチガチの独立事象です。

ここまで長々と書いておいて言うのもアレですが、データで検証する前から結果は分かりきっています。

出目データ検証のしがいがあるのは、インサイドベット(0~36)のほうです。

ライブルーレットでは、ディーラーは球を止める位置をある程度狙っています。

だから、出目に偏りや関係性が見つかるかもしれません。見つかれば、実際のベットに活かすことができます。

ここでは、

  • 0の直前の出目には何が多いのか?
  • 地雷ドマンの直前出目には何が多いのか?

を調べてみます。

ここで使う数式が分かれば、インサイドベットの他の検証も色々とできます。

0の直前出目の検証

赤黒などのアウトサイドベットは、0が出ない限りカジノ側が儲かりません。

赤黒の確率が48%前後になるのは0が一定確率で出るからです。

ということで、ライブルーレットのディーラーが0を狙ってくるタイミングが必ずあるはずです。

では、どういうときに0を狙ってくるのか?0の直前の出目には何が多いのか?を検証してみます。

手順① 0の直前の出目に印(✓)をつける

はじめに、0の1つ前の出目に印がつくように数式をいれます。印はなんでも良いのですが、ここでは✓にしています。↓

0直前出目数式01

=IF(OR(X3="",X4="⇦",X3<>0),"","✓")

「0直前」という名前の行を作り、その行の全セルに↑の数式を入れています。

  • 一つ前の出目のセルが空白
    =出目データがないとき
  • 1つ前の出目がデータの始まりのとき
  • 1つ前の出目が0でない(1 ~ 36)のとき

上の3通りの場合は、セルには空白が表示されるようにしています。
=IF(OR(X3="",X4="⇦",X3<>0),"" の部分ですね。

これ以外のとき(つまり、1つ前に出目データがあって、データの始まりではなく、出目が0のとき)には、✓が表示されるようになっています。

これで、0の1つ前の出目の下に✓印がつくようになりました。あとは集計です。

手順② 0~36 の各出目で確率を算出する

まず、0~36 の出目を並べた表をつくり、表内のセルに集計のための数式を入れていきます。↓

0直前出目の集計数式

=COUNTIFS($C$3:$NTR$3,C12,$C$8:$NTR$8,"✓")

たとえば、「出目の横一列の中から2に限定し、さらにその下に✓が付いているものだけを数えたい」というふうに、複数の条件で数えたいので、COUNTIFS関数を使います。

COUNTIFS関数
COUNTIFS関数は
=COUNTIFS([検索範囲A,検索条件A],[検索範囲B,検索条件B],[検索範囲C,検索条件C]…)
というふうに書きます。全ての条件を満たすセルの個数(データの個数)を出力してくれます。

上の例ですと

  • 出目データの行(C3 ~ NTR3)で、2 を探す
  • 「0直前」の行(C8 ~ NTR8)で、✓を探す

2つの条件を満たすセルの個数がCOUNTIFS関数で求まります。つまり、0直前の2の個数ですね。同様の数式が他の出目の箇所にも入っています。

 

次に、表中の「母数」のセルです。ここには、各出目の出現数を入れています。たとえば、2の出目なら、横一列にならぶ出目全体から2をCOUNTIF関数で数え上げればOKです。

母数

ただ、各データの塊の最後の出目は母数から除かないといけません。次に0が来ても、それは別の日にとったデータなので連続していないからです。

✓をつける数式でも、✓がつかないようにしているので、母数からも除外しておきます。ということで、母数のセルの数式はこうなります。↓

=COUNTIF($D$3:$NTR$3,C12)-COUNTIFS($D$3:$NTR$3,C12,$D$5:$NTR$5,"re")

前半の COUNTIF($D$3:$NTR$3,C12) の部分は、単純に2の出現回数のカウントです。

後半の
-COUNTIFS($D$3:$NTR$3,C12,$D$5:$NTR$5,"re")
の部分で、出目が2で、かつ「除外」の行に re と表示されているものを除外しています。

reは⇦マークの右隣りの出目に表示されるようにしています。1つのデータの塊の最後の出目ですね。remove(取り除く)の re です。

これで各出目の母数が算出できたので、あとは各出目について
✓マークの個数 ÷ 全体の出現回数
と割り算をした結果をパーセンテージ表示にしたのが「確率」のセルです。

0の直前出目の検証結果

各シートで同じ処理と集計を行って、全体を足すと10万投分の結果が出ます。↓

0直前出目10万投検証結果

直後に0が出やすい出目が知りたいのですが、このままでは分かりにくいです。

そこで、確率の高い順に並び替えます。

数式が入っているままだと不都合なので、表を数値だけの状態にします。

表全体をコピーしたらまずはそのまま貼り付けます。この状態ではまだ数式が入っています。

つぎに値の貼り付けを行います。右クリック>形式を選択して貼り付け で値の貼り付けを選べばOKです。数式は消えて、計算結果の数値がだけが残ります。↓

値貼り付け

値だけの表が出来たら、次はこれを確率順に並び替えます。

  1. 切り取り&貼り付けで表を縦一列にする
  2. フィルタをかける
  3. 降順に並び替える

という手順でやればOKです。↓

表の並び替え

確率の高い順に並び替えて、もとの形にしたのが下表です。↓

0直前出目確率順

一番左側の10個が、直後に0が来やすい出目TOP10となります。「だから何?」という感が否めませんがw

でも例えば、「13が来たら直後に0に1点賭け」というシンプルなロジックでも利益が出るということです。$1ベットで1,000回賭けたら、約$184の利益になります。

ただ、これはあくまでも僕が集めた10万投のデータ上の話。今後はこの通りになるかどうかは分かりません。おそらくこの通りにはなりません。

ガチムチ
・・・(怒)

なっとー
…はい。ちょっと目線を変えてみます。

この検証結果をそのままベット手法に使うのはさすがに危険ですが、傾向は分かるかもしれません。ということで、TOP10の出目をウィール上に表示してみました。

こうやって見ると、左上と右下の出目から0に行きやすいことが分かります。

4 と 14 はTOP10に入っているものの理論値(2.70%)よりも低いので、この2つを除外するとこの傾向はさらに明確になります。

この傾向を知っていれば、

「0や0の近くの出目がしばらく出ていない」という状況で、13などのTOP10出目が来た

というときには、0一点賭けや0周りのネイバーベットで仕掛けると優位性があると思われます。

 

こんな感じで、出目の間の関係性を調べていくと、実際のベットに使える情報が得られることも多いです。

ここまでは0という1つの出目だけに注目していましたが、複数の出目についても同じ分析が出来ます。

地雷ドマン直前出目の検証

下半身鬼尾
地雷???

ビチ子
ドマン???♡

 

 

「地雷ドマン」とは、地雷ベッティングの高配当出目のことです。

地雷ベット配置

上のように、3rdエリアにまるで地雷原のようにフラワーベットで賭けるベット手法、それが地雷ベットです。

ベット配置を見ると分かりますが、26 29 32 35 の4つに来ると高配当となっています。置かれたチップたちの「ド真ん中」にあるので、高配当出目を「ドマン」と呼んでいます。

26 29 32 35 はどれも0周辺にあるので、ディーラーが0周りを狙いだしたと感じたときに使います。0にもチップを置いているのは、0に入ったときに悔しいからです。

地雷ベットはドマンにくれば一発で利益が乗って勝ち逃げしやすいので、コミュニティ内で愛用者が多いです。僕もその一人です。

ということで、地雷のドマン直前に多い出目は何なのか?、次に調べてみます。

手順① ドマンの直前出目に✓をつける

基本的な流れは0直前出目のときと同じです。

地雷ドマン出目である 26 29 32 35 0 の前の出目に✓がつくように数式を入れていきます。

地雷ドマン直前出目検証数式

=IF(OR(E3="",D5="⇦",D3=""),"",IF(OR(D3=29,D3=35,D3=26,D3=0,D3=32),"✓",""))

=IF(OR(E3="",D5="⇦",D3=""),"" の部分は、データがない場合とデータ境界を除外するためのもので、これまでと同様です。

実質的な中身は↓の部分です。

IF(OR(D3=29,D3=35,D3=26,D3=0,D3=32),"✓","")

OR関数をIF関数の論理式に使っています。

「直後の出目が29 35 26 0 32 のいずれかである場合、✓を表示。それ以外なら空白」

という意味です。これまで登場した数式と同じですね。

この数式を「3rdドマン直前」の行にあるセル全てにコピペして、準備完了です。

手順② 0 ~ 36 の各出目で確率を算出する

これも0直前出目のときと全く同じ流れです。

✓マークさえ付してしまえば、カウント方法や母数の算出は0直前出目の検証のときと同様にやればOKです。

地雷ドマン直前出目の検証結果

地雷3rd直前出目降順

TOP10をウィール上に表示すると、↓のようになります。
パッと見で分かるのが、0直前出目と共通する部分が多いということです。
違うのは、出目が左側に少し偏っている点ですね。地雷ドマン出目は左上ゾーンに多いので、これが影響しているのかもしれません。
このように、直前出目を調べてみるだけでも、色々と発見があります。
アイディア次第で、もっと面白くて実用性のある検証が出来るかもしれません。ぜひトライしてみてください。

出目エリアの色付けの方法

エクセル上の出目の部分は、実際の出目の色になるように設定しています。

分析する上では、別に色付けしなくても全く問題ないのですが、雰囲気が出るのでオススメです。

手順① 各出目の上に赤・黒・緑と表示させる

普段は行全体を非表示にして隠しているのですが、各出目の上には色の名前が表示されています。

出目エリアの装飾方法01
数式のうち、ISBLANK関数を除いた部分は次のようになっています。↓

INDEX(リスト!$E$3:$E$39,MATCH(C3,リスト!$B$3:$B$39,0),1)

INDEX関数とMATCH関数を組み合わせて使っています。

「リスト」というシートに、赤黒・ハイロー・ウィール上の位置などの各出目の情報をまとめているので、そこから関数で引っ張ってきています。

リストシート

ただ、INDEX関数とMATCH関数について説明しはじめると、せっかく終わりかけたこの記事がおわらなくなるので、省略いたします。

「エクセル INDEX MATCH」でググれば、解説ページや動画がたくさん出てきます。

手順② 条件付き書式を数式で指定する

赤・黒・緑 を各出目の上に表示させたら、あとは条件付き書式を出目エリアに設定するだけです。

出目エリア全体を選択した状態で、
ホーム > 条件付き書式 > 新しいルール
とクリックしていきます。

次に、いくつかある項目のうち、「数式を使用して、書式設定するセルを決定」を選びます。

すると数式の入力欄が出てきますので、そこに数式を入れます。

条件付き書式

数式を入れるときは、書式設定するエリアの一番左上のセルに対応する数式を入れます。

今回の場合、書式設定する範囲はC3~NTR3ですので、C3セルだけを書式設定するイメージで数式を入れればOKです。

C3セルの1つ上のC2セルが「赤」なら書式を変えたいので、数式には「=C2="赤"」と入れます。
書式設定で数式を使うときには、一番左に"="が必要ですので要注意です。

数式を入れたら、書式を設定すればOKです。ここでは「赤色の塗りつぶし・文字色は白」としています。

全部おわったら「OK」ボタンをクリックすれば完了です。全てのセルに条件付き書式設定が加わりました。

同じことを黒と緑にもやれば、実際のルーレットの色と同じになって雰囲気が出ます。

まとめ

かなり長くなってしまいましたが、ここでご紹介した数式を使えば、色々と自由に検証できるはずです。

特にインサイドベットの検証は、偏りや出目間の関係性が発見できるので面白いです。

ぜひ出目データを集めて、あなた独自の検証をして勝てるベット手法を見つけ出してください!

ガチムチ
そんなメンドイことできるか!このガリ勉野郎が!

なっとー
ですよねー。

出目データを集めるのはマジで大変なので、ぜひ僕の集めたデータを使ってください。

コミュニティに入って頂ければ、10万投のデータを自由に使うことができます(本入会の場合)。

コミュニティ内には「みんなの検証部屋」という部屋があるので、そこで皆でワイワイ楽しく検証しています。検証仲間募集中です!

オンラインコミュニティー
オンラインカジノで『ガチで勝ちたい人』のみが集まったオンカジ攻略コミュニティー。
実践報告をする環境があることで、今より各段に勝率は上がります。コミュニティー内の勝ち組率は73%!!
その他にも、実際に勝っているメンバーさんの立ち回り方法や手法も見放題!質問もOK!
有益な情報がここには詰まっているといっても過言ではない環境です。
値上げ前の今が入会のチャンスです!!

chome
私たちと本気で勝ち組を目指しませんか?!

お礼メールの嵐!過去に『380万円稼がせた』伝説的ルーレット攻略法

私はオンラインカジノのルーレットにおいて過去3年間で一度もマイナス収益となったことがありません。それは長年の経験による資金管理・メンタルコントールもさることながら、真剣にルーレットに取り組み様々な手法・ライブゲーム80万投分のデータ分析を行った成果だと思っています。今もなお私が軸として使用しているルーレット攻略法『極ルーレット十連法』は、配布させていただいた皆さんから約80%の確率でお礼のメールを頂けるほど効果の高いルーレット攻略法です。

kome
このお礼メールはごくごく一部です。ちなみに電子書籍のオファーも頂けました(笑)
おすすめの記事